Functie ALS.VOORWAARDEN in Excel

De ALS functie is één van de meest gebruikte functies in Excel. Hiermee kun je Excel laten kiezen tussen twee uitkomsten, afhankelijk van een voorwaarde. Je bepaalt eerst zelf wat Excel moet testen, en laat daarna Excel weten wat het moet doen als dat klopt, en wat er moet gebeuren als dat niet het geval is.

In sommige gevallen wil je meer dan één voorwaarde invoeren. Je wilt bijvoorbeeld Excel iets laten doen bij een hoge waarde, een gemiddelde waarde en een lage waarde. Het is in Excel gebruikelijk om dit op te lossen door de ALS functie te nesten.

Je gebruikt hierbij de ALS functie als argument binnen een andere ALS functie. Dit klinkt lastiger dan het is, maar je formules kunnen hierdoor wel lang worden en lastig om te lezen.

Excel heeft een goed alternatief voor de geneste ALS functie, namelijk de functie ALS.VOORWAARDEN. Hiermee kun je meerdere voorwaarden opgeven, zonder dat je daar meerdere functies voor nodig hebt. Dit resulteert in kortere, en gemakkelijker te begrijpen formules.

Schrijfwijze formule

=ALS.VOORWAARDEN(logische_test1; waarde_als_waar1; [logische_test2; waarde_als_waar2]; …)

Argumenten

• logische_test1: Hier voer je de eerste voorwaarde in die Excel moet controleren. Bijvoorbeeld A1>10 (de inhoud van cel A1 is groter dan 10).
• waarde_als_waar1: Hier voer je in wat Excel moet tonen of berekenen als de eerste voorwaarde WAAR is.

Optioneel kun je meerdere logische testen en waarde als waar opgeven. Het is hierbij belangrijk om te begrijpen dat Excel deze voorwaarden van boven naar beneden bij langs gaat, en stopt zodra het een voorwaarde tegenkomt die waar is.

Wanneer je deze functie gebruikt, is de kans groot dat je al eens eerder de ‘normale’ ALS functie hebt gebruikt. De ALS functie heeft ook een argument waarde_als_onwaar, waarmee je Excel laat weten wat het moet doen als de voorwaarde niet klopt.

De functie ALS.VOORWAARDEN heeft dit argument niet. Als geen enkele voorwaarde waar is, geeft Excel een foutmelding. Dit is gelukkig eenvoudig op te lossen, zoals je later in de voorbeelden zult zien.

Voorbeeld: voorraadstatus

Op deze website staat een artikel met uitleg over hoe je functies kunt nesten. Hier wordt ook een voorbeeld laten zien waarbij de geneste ALS functie wordt toegepast.

Om te laten zien dat je de functie ALS.VOORWAARDEN als goed alternatief kunt gebruiken, zal hetzelfde voorbeeld worden gebruikt.

In kolom B staat de voorraad per product. In kolom C willen we automatisch een status tonen op basis van de voorraad:

• 0 – Niet op voorraad
• Minder dan 5 – Bijna op
• Minder dan 10 – Lage voorraad
• 10 of meer – Op voorraad

De voorwaarden kun je maken met behulp van vergelijkingsoperatoren:

• B2=0;"Niet op voorraad"
• B2<5;"Bijna op"
• B2<10;"Lage voorraad"
• B2>=10;"Op voorraad"

Wanneer je dit als argumenten invoert in de functie ALS.VOORWAARDEN, krijg je de volgende formule:

=ALS.VOORWAARDEN(B2=0;"Niet op voorraad";B2<5;"Bijna op";B2<10;"Lage voorraad";B2>=10;"Op voorraad")

Je kunt bij het invoeren van de formule eventueel gebruik maken van het venster ‘Functie invoegen’. Dan ziet het er als volgt uit:

Wanneer je ALS functies nest, dan ziet de formule er als volgt uit:

=ALS(B2=0;"Niet op voorraad";ALS(B2<5;"Bijna op";ALS(B2<10;"Lage voorraad";"Op voorraad")))

Het resultaat is hetzelfde, maar het maken van de formule is wat lastiger omdat je met meerdere functies moet werken en rekening moet houden met de haakjes.

Waarom de volgorde van argumenten van belang is

Als je wilt dat Excel het juiste resultaat toont, is het erg belangrijk de volgorde van voorwaarden correct is. Excel werkt namelijk altijd van boven naar beneden.

Stel we gebruiken de volgende formule:

=ALS.VOORWAARDEN(B2<10;"Lage voorraad";B2<5;"Bijna op";B2=0;"Niet op voorraad";B2>=10;"Op voorraad")

De voorwaarden zijn precies hetzelfde, enkel de volgorde is aangepast. Maar zoals je kunt zien kloppen de statussen nu niet meer, omdat een voorraad van 2 ook voldoet aan B2<10.

Excel kiest hierdoor direct voor ‘Lage voorraad’. De voorwaarden ‘Bijna op’ en ‘Niet op voorraad’ worden nooit bereikt.

Oplossing als geen enkele voorwaarde waar is

Zoals je hebt kunnen zien heeft deze functie geen standaard ‘anders’ argument. Dit kun je oplossen door als laatste voorwaarde WAAR te gebruiken.

Stel dat we de formule iets aanpassen en geen voorwaarde opgeven voor ’10 of meer’. De formule wordt dan:

=ALS.VOORWAARDEN(B2=0;"Niet op voorraad";B2<5;"Bijna op";B2<10;"Lage voorraad")

Bij de voorraad van 12 is geen enkele voorwaarde waar. Excel geeft dan een foutmelding (in cel C5), omdat ALS.VOORWAARDEN altijd minimaal één ware voorwaarde verwacht.

Dit is een belangrijk verschil met de gewone ALS functie, die wel een waarde-als-onwaar heeft.

Om dit op te lossen, kun je aan het einde een voorwaarde met WAAR toevoegen:

=ALS.VOORWAARDEN(B2=0;"Niet op voorraad";B2<5;"Bijna op";B2<10;"Lage voorraad";WAAR;"Op voorraad")

Excel controleert nu eerst alle specifieke voorwaarden. Als geen daarvan klopt, komt Excel automatisch bij WAAR. Dit werkt vergelijkbaar met ‘waarde-als-onwaar’ in de gewone ALS functie.